跳转到内容
语言参考Zig 0.17.1官方原文
test_if.zig
// if 表达式有三种用法,对应三种类型:
// * bool
// * ?T
// * anyerror!T
const expect = @import("std").testing.expect;
const expectEqual = @import("std").testing.expectEqual;
test "if expression" {
// 使用 if 表达式替代三元表达式。
const a: u32 = 5;
const b: u32 = 4;
const result = if (a != b) 47 else 3089;
try expectEqual(result, 47);
}
test "if boolean" {
// if 表达式测试布尔条件。
const a: u32 = 5;
const b: u32 = 4;
if (a != b) {
try expect(true);
} else if (a == 9) {
unreachable;
} else {
unreachable;
}
}
test "if error union" {
// if 表达式检查错误。
// 注意 else 上的 |err| 捕获。
const a: anyerror!u32 = 0;
if (a) |value| {
try expectEqual(value, 0);
} else |err| {
_ = err;
unreachable;
}
const b: anyerror!u32 = error.BadValue;
if (b) |value| {
_ = value;
unreachable;
} else |err| {
try expectEqual(err, error.BadValue);
}
// 必须提供 else 和 |err| 捕获。
if (a) |value| {
try expectEqual(value, 0);
} else |_| {}
// 如果只检查错误值,使用空块表达式。
if (b) |_| {} else |err| {
try expectEqual(err, error.BadValue);
}
// 使用指针捕获,通过引用访问该值。
var c: anyerror!u32 = 3;
if (c) |*value| {
value.* = 9;
} else |_| {
unreachable;
}
if (c) |value| {
try expectEqual(value, 9);
} else |_| {
unreachable;
}
}
命令行
$ zig test test_if.zig
1/3 test_if.test.if expression...OK
2/3 test_if.test.if boolean...OK
3/3 test_if.test.if error union...OK
All 3 tests passed.

对可选值使用 if

test_if_optionals.zig
const expect = @import("std").testing.expect;
const expectEqual = @import("std").testing.expectEqual;
test "if optional" {
// if 表达式检查空值。
const a: ?u32 = 0;
if (a) |value| {
try expectEqual(0, value);
} else {
unreachable;
}
const b: ?u32 = null;
if (b) |_| {
unreachable;
} else {
try expect(true);
}
// else 不是必需的。
if (a) |value| {
try expectEqual(0, value);
}
// 如果只检查是否为空,使用二元相等运算符。
if (b == null) {
try expect(true);
}
// 使用指针捕获,通过引用访问该值。
var c: ?u32 = 3;
if (c) |*value| {
value.* = 2;
}
if (c) |value| {
try expectEqual(2, value);
} else {
unreachable;
}
}
test "if error union with optional" {
// if 表达式先检查错误,再解包可选值。
// |optional_value| 捕获的类型为 ?u32。
const a: anyerror!?u32 = 0;
if (a) |optional_value| {
try expectEqual(0, optional_value.?);
} else |err| {
_ = err;
unreachable;
}
const b: anyerror!?u32 = null;
if (b) |optional_value| {
try expectEqual(null, optional_value);
} else |_| {
unreachable;
}
const c: anyerror!?u32 = error.BadValue;
if (c) |optional_value| {
_ = optional_value;
unreachable;
} else |err| {
try expectEqual(error.BadValue, err);
}
// 每次都使用指针捕获,即可通过引用访问该值。
var d: anyerror!?u32 = 3;
if (d) |*optional_value| {
if (optional_value.*) |*value| {
value.* = 9;
}
} else |_| {
unreachable;
}
if (d) |optional_value| {
try expectEqual(9, optional_value.?);
} else |_| {
unreachable;
}
}
命令行
$ zig test test_if_optionals.zig
1/2 test_if_optionals.test.if optional...OK
2/2 test_if_optionals.test.if error union with optional...OK
All 2 tests passed.

另见: