跳转到内容
语言参考Zig 0.17.1官方原文

某些场景需要直接控制 Zig 程序生成的机器码,而不能依赖 Zig 的代码生成。此时可以使用内联汇编。以下示例在 x86_64 Linux 上使用内联汇编实现 Hello, World:

inline_assembly.zig
pub fn main() noreturn {
const msg = "hello world\n";
_ = syscall3(SYS_write, STDOUT_FILENO, @intFromPtr(msg), msg.len);
_ = syscall1(SYS_exit, 0);
unreachable;
}
pub const SYS_write = 1;
pub const SYS_exit = 60;
pub const STDOUT_FILENO = 1;
pub fn syscall1(number: usize, arg1: usize) usize {
return asm volatile ("syscall"
: [ret] "={rax}" (-> usize),
: [number] "{rax}" (number),
[arg1] "{rdi}" (arg1),
: .{ .rcx = true, .r11 = true });
}
pub fn syscall3(number: usize, arg1: usize, arg2: usize, arg3: usize) usize {
return asm volatile ("syscall"
: [ret] "={rax}" (-> usize),
: [number] "{rax}" (number),
[arg1] "{rdi}" (arg1),
[arg2] "{rsi}" (arg2),
[arg3] "{rdx}" (arg3),
: .{ .rcx = true, .r11 = true });
}
命令行
$ zig build-exe inline_assembly.zig -target x86_64-linux
$ ./inline_assembly
hello world

语法解析如下:

Assembly Syntax Explained.zig
pub fn syscall1(number: usize, arg1: usize) usize {
// 内联汇编是会返回一个值的表达式。
// 表达式由 `asm` 关键字开始。
return asm
// `volatile` 是可选修饰符,用来告知 Zig 此
// 内联汇编表达式具有副作用。如果没有
// `volatile`,当结果未使用时,Zig 可以删除
// 该内联汇编代码。
volatile (
// 接下来是包含汇编代码的编译时字符串。
// 如果使用了寄存器约束字符串,在需要寄存器的位置,
// 可以在字符串中使用 `%[ret]`、`%[number]`
// 或 `%[arg1]`,指定 Zig 为参数或返回值
// 使用的寄存器。不过,
// 下方代码没有使用这一方式。字面量 `%` 可以
// 用两个百分号转义得到:`%%`。
// 此处多行字符串语法通常很有用。
\\syscall
// 接下来是输出。未来 Zig 是否支持
// 多个输出,取决于
// https://github.com/ziglang/zig/issues/215 的解决方式。
// 允许没有输出;此时这个冒号后面会
// 直接跟随表示输入的冒号。
:
// 这里指定在上述汇编字符串的 `%[ret]` 语法中
// 使用的名称。本例没有使用它,
// 但语法要求必须提供。
[ret]
// 接下来是输出约束字符串。此功能在 Zig 中
// 仍视为不稳定,因此必须参考 LLVM/GCC 文档
// 理解语义。
// http://releases.llvm.org/10.0.0/docs/LangRef.html#inline-asm-constraint-string
// https://gcc.gnu.org/onlinedocs/gcc/Extended-Asm.html
// 本例中,约束字符串的意思是“此内联汇编指令
// 的结果值就是 $rax 中的内容”。
"={rax}"
// 接下来是值绑定,或者 `->` 后跟类型。
// 该类型就是内联汇编表达式的结果类型。
// 如果是值绑定,则使用 `%[ret]` 语法
// 引用绑定到该值的寄存器。
(-> usize),
// 接下来是输入列表。
// 这些输入约束的意思是:“执行汇编代码时,
// $rax 应具有 `number` 的值,$rdi 应具有
// `arg1` 的值”。允许任意数量的输入参数,
// 也可以没有输入参数。
: [number] "{rax}" (number),
[arg1] "{rdi}" (arg1),
// 接下来是破坏声明列表,用来声明一组寄存器,
// 它们的值在执行汇编后不保证保留。
// 不包括输入或输出寄存器。特殊的破坏声明值
// "memory" 表示汇编会写入任意未声明的
// 内存位置,而不仅仅是已声明的间接
// 输出所指向的内存。本例列出 $rcx 和 $r11,
// 因为已知内核系统调用不会保留这些寄存器。
: .{ .rcx = true, .r11 = true });
}

对于 x86 和 x86_64 目标,使用 AT&T 语法,而不是更常见的 Intel 语法。这源于技术限制:汇编解析由 LLVM 提供,而其 Intel 语法支持存在缺陷,也未经过充分测试。

Zig 将来可能拥有自己的汇编器,以便更紧密地融入语言,并兼容常见的 NASM 语法。在发布 1.0.0 之前,本节文档将更新,明确说明 AT&T 与 Intel/NASM 语法的最终支持状态。

输出约束

Zig 中的输出约束仍视为不稳定功能,因此必须参考 LLVM 文档和 GCC 文档理解其语义。

注意,议题 #215 计划对输出约束做出一些破坏性修改。

输入约束

Zig 中的输入约束仍视为不稳定功能,因此必须参考 LLVM 文档和 GCC 文档理解其语义。

注意,议题 #215 计划对输入约束做出一些破坏性修改。

破坏声明

破坏声明是执行汇编代码后不保证保留值的寄存器集合,不包括输入或输出寄存器。特殊的破坏声明值 "memory" 表示汇编会写入任意未声明的内存位置,而不仅仅是已声明的间接输出所指向的内存。

未完整声明某个内联汇编表达式的全部破坏项,属于不进行检查的非法行为。

全局汇编

汇编表达式出现在命名空间级的 comptime 块中时,称为全局汇编。

这种汇编的规则与内联汇编不同。首先,volatile 无效,因为所有全局汇编都会无条件包含。其次,没有输入、输出或破坏声明。所有全局汇编都逐字拼接成一个长字符串,再一起汇编。它不像内联汇编表达式那样具有关于 % 的模板替换规则。

test_global_assembly.zig
const std = @import("std");
const expectEqual = std.testing.expectEqual;
comptime {
asm (
\\.global my_func;
\\.type my_func, @function;
\\my_func:
\\ lea (%rdi,%rsi,1),%eax
\\ retq
);
}
extern fn my_func(a: i32, b: i32) i32;
test "global assembly" {
try expectEqual(46, my_func(12, 34));
}
命令行
$ zig test test_global_assembly.zig -target x86_64-linux -fllvm
1/1 test_global_assembly.test.global assembly...OK
All 1 tests passed.