向量
向量是一组并行处理的布尔值、整数、浮点数或指针,条件允许时使用 SIMD 指令。向量类型通过内置函数 @Vector 创建。
向量通常支持与其基础类型相同的内置运算符。唯一例外是布尔向量上的 and 和 or 关键字,因为它们会影响控制流,而向量不允许这样做。其他运算均按元素执行,并返回与输入向量等长的向量,包括:
- 算术运算(
+、-、/、*、@divFloor、@sqrt、@ceil、@log等) - 按位运算符(
>>、<<、&、|、~等) - 比较运算符(
<、>、==等) - 布尔非(
!)
禁止在同一次数学运算中混用标量(单个数值)和向量。Zig 提供 @splat 内置函数,便于将标量转换为向量;也支持通过 @reduce 和数组索引语法将向量转换为标量。向量还支持与长度在编译时已知的定长数组相互赋值。
要在向量内部或向量之间重排元素,Zig 提供 @shuffle 和 @select 函数。
短于目标机器原生 SIMD 宽度的向量运算通常编译为单条 SIMD 指令,更长的向量则编译为多条 SIMD 指令。如果目标架构没有对应运算的 SIMD 支持,编译器默认逐个处理向量元素。Zig 支持编译时已知且不超过 2^32-1 的任意向量长度,不过通常使用较小的 2 的幂长度(2–64)。注意,过长的向量(例如 2^20)在当前 Zig 版本中可能导致编译器崩溃。
const std = @import("std");
const expectEqual = std.testing.expectEqual;
test "Basic vector usage" {
// 向量的长度和基础类型在编译时已知。
const a = @Vector(4, i32){ 1, 2, 3, 4 };
const b = @Vector(4, i32){ 5, 6, 7, 8 };
// 数学运算按元素进行。
const c = a + b;
// 可以使用数组索引语法访问单个向量元素。
try expectEqual(6, c[0]);
try expectEqual(8, c[1]);
try expectEqual(10, c[2]);
try expectEqual(12, c[3]);
}
test "Conversion between vectors, arrays, and slices" {
// 向量可以强制转换为数组,反之亦然。
const arr1: [4]f32 = [_]f32{ 1.1, 3.2, 4.5, 5.6 };
const vec: @Vector(4, f32) = arr1;
const arr2: [4]f32 = vec;
try expectEqual(arr1, arr2);
// 也可以使用 .* 将编译时已知长度的切片赋值给向量
const vec2: @Vector(2, f32) = arr1[1..3].*;
const slice: []const f32 = &arr1;
var offset: u32 = 1; // 使用 var 使其仅在运行时已知
_ = &offset; // 抑制“变量从未被修改”的错误
// 若要从运行时已知的偏移处提取编译时已知的长度,
// 先从起始偏移提取新切片,再提取一个
// 编译时已知长度的数组
const vec3: @Vector(2, f32) = slice[offset..][0..2].*;
try expectEqual(slice[offset], vec2[0]);
try expectEqual(slice[offset + 1], vec2[1]);
try expectEqual(vec2, vec3);
}$ zig test test_vector.zig
1/2 test_vector.test.Basic vector usage...OK
2/2 test_vector.test.Conversion between vectors, arrays, and slices...OK
All 2 tests passed.
待补充:C ABI 互操作
待考虑:建议使用 std.MultiArrayList
另见:
与数组的关系
向量与数组都具有明确定义的位布局,因此支持彼此通过 @bitCast 转换。类型强制转换会隐式执行 @bitCast。
数组具有明确定义的字节布局,向量则没有,因此在两者之间执行 @ptrCast 属于非法行为。
向量解构
向量可以解构:
const print = @import("std").debug.print;
// 模拟 punpckldq
pub fn unpack(x: @Vector(4, f32), y: @Vector(4, f32)) @Vector(4, f32) {
const a, const c, _, _ = x;
const b, const d, _, _ = y;
return .{ a, b, c, d };
}
pub fn main() void {
const x: @Vector(4, f32) = .{ 1.0, 2.0, 3.0, 4.0 };
const y: @Vector(4, f32) = .{ 5.0, 6.0, 7.0, 8.0 };
print("{}", .{unpack(x, y)});
}$ zig build-exe destructuring_vectors.zig
$ ./destructuring_vectors
{ 1, 5, 2, 6 }
另见: