跳转到内容
语言参考Zig 0.17.1官方原文
test_for.zig
const expectEqual = @import("std").testing.expectEqual;
test "for basics" {
const items = [_]i32{ 4, 5, 3, -1, 4 };
var sum: i32 = 0;
// for 循环用于遍历切片和数组。
for (items) |value| {
// 支持 break 和 continue。
if (value < 0) {
continue;
}
sum += value;
}
try expectEqual(16, sum);
// 使用切片遍历切片或数组的一部分。
sum = 0;
for (items[0..2]) |value| {
sum += value;
}
try expectEqual(9, sum);
}
test "for ranges" {
const items = [_]u8{1, 2, 3};
var sum: usize = 0;
// 要访问迭代索引,请将无界范围指定为
// 第二个迭代对象,并提供第二个捕获值。
for (items, 0..) |e, i| {
try expectEqual(usize, @TypeOf(i));
sum += i;
try expectEqual(e, i + 1);
}
try expectEqual(3, sum); // 0 + 1 + 2
// 要遍历连续整数,请使用有界范围语法。
// 单独使用无界范围会导致编译错误。
sum = 0;
for (0..5) |i| {
sum += i;
}
try expectEqual(10, sum);
}
test "multi object for" {
const items = [_]usize{ 1, 2, 3 };
const items2 = [_]usize{ 4, 5, 6 };
var count: usize = 0;
// 同时遍历多个对象。
// 所有有界对象的长度必须相同。
// 至少要有一个有界对象。
for (items, items2) |i, j| {
count += i + j;
}
try expectEqual(21, count);
}
test "for reference" {
var items = [_]i32{ 3, 4, 2 };
// 将捕获值指定为指针,
// 即可通过引用遍历切片。
for (&items) |*value| {
value.* += 1;
}
try expectEqual(4, items[0]);
try expectEqual(5, items[1]);
try expectEqual(3, items[2]);
}
test "for else" {
// 与 while 循环一样,for 也可以带有 else。
// 循环未通过 break 退出时,才会执行 else 分支。
const items = [_]i32{ 3, 4, 5 };
const result = for (items) |value| {
if (value > 10) break value;
} else 0;
try expectEqual(0, result);
const more_items = [_]i32{ 3, 4, 11, 5 };
const another_result = for (more_items) |value| {
if (value > 10) break value;
} else 0;
try expectEqual(11, another_result);
}
命令行
$ zig test test_for.zig
1/5 test_for.test.for basics...OK
2/5 test_for.test.for ranges...OK
3/5 test_for.test.multi object for...OK
4/5 test_for.test.for reference...OK
5/5 test_for.test.for else...OK
All 5 tests passed.

带标签的 for

为 for 循环添加标签后,可以在嵌套循环中通过 break 或 continue 引用它:

test_for_nested_break.zig
const std = @import("std");
const expectEqual = std.testing.expectEqual;
test "nested break" {
var count: usize = 0;
outer: for (1..6) |_| {
for (1..6) |_| {
count += 1;
break :outer;
}
}
try expectEqual(1, count);
}
test "nested continue" {
var count: usize = 0;
outer: for (1..9) |_| {
for (1..6) |_| {
count += 1;
continue :outer;
}
}
try expectEqual(8, count);
}
命令行
$ zig test test_for_nested_break.zig
1/2 test_for_nested_break.test.nested break...OK
2/2 test_for_nested_break.test.nested continue...OK
All 2 tests passed.

inline for

for 循环可以内联。内联会展开循环,使代码能够执行仅在编译时可行的操作,例如将类型作为一等值使用。内联 for 循环的捕获值和迭代器值都在编译时已知。

test_inline_for.zig
const expectEqual = @import("std").testing.expectEqual;
test "inline for loop" {
const nums = [_]i32{ 2, 4, 6 };
var sum: usize = 0;
inline for (nums) |i| {
const T = switch (i) {
2 => f32,
4 => i8,
6 => bool,
else => unreachable,
};
sum += typeNameLength(T);
}
try expectEqual(9, sum);
}
fn typeNameLength(comptime T: type) usize {
return @typeName(T).len;
}
命令行
$ zig test test_inline_for.zig
1/1 test_inline_for.test.inline for loop...OK
All 1 tests passed.

建议仅在以下情况之一成立时使用 inline 循环:

  • 需要循环在编译时执行,才能实现所需语义。
  • 已有基准测试证明,以这种方式强制展开循环会带来可测量的性能提升。

另见: