跳转到内容
标准库Zig 0.17.0官方原文
源码std/treap.zig

第 1 行

std.treap.assert

别名

第 2 行

别名目标 std.debug.assert

std.treap.findFirstGreaterOrEqual

函数

第 608 行

fn findFirstGreaterOrEqual(array: []u64, value: u64) usize

参数

array: []u64
value: u64

std.treap.Order

别名

第 4 行

别名目标 std.math.Order

std.treap.SliceIterRandomOrder

类型函数

第 314 行

fn SliceIterRandomOrder(comptime T: type) type

参数

T: type

字段

rng: std.Random
slice: []T
index: usize = undefined
offset: usize = undefined
co_prime: usize

std.treap.SliceIterRandomOrder.init

函数

第 324 行

pub fn init(slice: []T, rng: std.Random) Self

参数

slice: []T
rng: std.Random

std.treap.SliceIterRandomOrder.next

函数

第 349 行

pub fn next(self: *Self) ?*T

参数

self: *Self

std.treap.SliceIterRandomOrder.reset

函数

第 344 行

pub fn reset(self: *Self) void

参数

self: *Self

std.treap.SliceIterRandomOrder.Self

别名

第 322 行

别名目标 std.treap.SliceIterRandomOrder

std.treap.std

别名

第 1 行

别名目标 std

std.treap.testing

别名

第 3 行

别名目标 std.testing

std.treap.TestNode

常量

第 358 行

std.treap.testOrderedArrayAndTreapConsistency

函数

第 614 行

fn testOrderedArrayAndTreapConsistency(array: []u64, treap: *TestTreap) !void

参数

array: []u64
treap: *TestTreap

std.treap.TestTreap

类型

第 357 行

std.treap.Treap

类型函数

第 6 行

pub fn Treap(comptime Key: type, comptime compareFn: anytype) type

参数

Key: type

字段

root: ?*Node = null
prng: Prng = .{}

std.treap.Treap.compare

函数

第 12 行

fn compare(a: Key, b: Key) Order

参数

a: Key
b: Key

std.treap.Treap.Entry

容器

第 132 行

Entry 表示树堆中与给定键关联的槽位。

字段

key: Key

此条目关联的键。

treap: *Self

引用此条目所属的树堆。

node: ?*Node

此条目处的当前节点。

context: union(enum) {
    /// 已对此条目调用 find(),其在树堆中的位置已知。
    inserted_under: ?*Node,
    /// 条目的节点已从树堆中移除,必须重新查找才能修改。
    removed,
}

条目的当前状态。

std.treap.Treap.Entry.set

函数

第 149 行

用新节点更新树堆中此 Entry 处的节点;null 表示删除。new_node 的内容可以为 undefind,因为会在内部初始化其值。

pub fn set(self: *Entry, new_node: ?*Node) void

参数

self: *Entry
new_node: ?*Node

std.treap.Treap.extremeInSubtreeOnDirection

函数

第 63 行

fn extremeInSubtreeOnDirection(node: *Node, direction: u1) *Node

参数

node: *Node
direction: u1

std.treap.Treap.find

函数

第 180 行

fn find(self: Self, key: Key, parent_ref: *?*Node) ?*Node

参数

self: Self
key: Key
parent_ref: *?*Node

std.treap.Treap.getEntryFor

函数

第 105 行

在树堆中查找给定键的 Entry。 Entry 充当树堆中的槽位,用于插入、替换或移除关联该键的节点。

pub fn getEntryFor(self: *Self, key: Key) Entry

参数

self: *Self
key: Key

std.treap.Treap.getEntryForExisting

函数

第 120 行

获取当前存在于树堆中的 Node 的条目。 如果 Node 当前未插入树堆,则为未定义行为。 Entry 充当树堆中的槽位,用于插入/替换/移除与该键关联的节点。

pub fn getEntryForExisting(self: *Self, node: *Node) Entry

参数

self: *Self
node: *Node

std.treap.Treap.getMax

函数

第 98 行

返回树堆中按键最大的 Node(若存在)。 使用 getEntryForExisting() 替换或移除此 Node。

pub fn getMax(self: Self) ?*Node

参数

self: Self

std.treap.Treap.getMin

函数

第 91 行

返回树堆中按键最小的 Node(若存在)。 使用 getEntryForExisting() 替换或移除此 Node。

pub fn getMin(self: Self) ?*Node

参数

self: Self

std.treap.Treap.inorderIterator

函数

第 306 行

pub fn inorderIterator(self: *Self) InorderIterator

参数

self: *Self

std.treap.Treap.InorderIterator

容器

第 293 行

用法示例: var iter = treap.inorderIterator(); while (iter.next()) |node| { ... }

字段

current: ?*Node

std.treap.Treap.InorderIterator.next

函数

第 296 行

pub fn next(it: *InorderIterator) ?*Node

参数

std.treap.Treap.insert

函数

第 196 行

fn insert(self: *Self, key: Key, parent: ?*Node, node: *Node) void

参数

self: *Self
key: Key
parent: ?*Node
node: *Node

std.treap.Treap.nextOnDirection

函数

第 69 行

fn nextOnDirection(node: *Node, direction: u1) ?*Node

参数

node: *Node
direction: u1

std.treap.Treap.Node

容器

第 49 行

Node 表示树堆中的项目或节点,具有唯一关联键。

字段

key: Key
priority: usize
parent: ?*Node
children: [2]?*Node

std.treap.Treap.Node.next

函数

第 55 行

pub fn next(node: *Node) ?*Node

参数

node: *Node

std.treap.Treap.Node.prev

函数

第 58 行

pub fn prev(node: *Node) ?*Node

参数

node: *Node

std.treap.Treap.Prng

容器

第 22 行

为树堆定制的伪随机数生成器。 它仅用于减小树堆本身的内存大小, 因为 std.Random.DefaultPrng 需要更大的状态,当然也提供更好的随机熵。

字段

xorshift: usize = 0

std.treap.Treap.Prng.random

函数

第 25 行

fn random(self: *Prng, seed: usize) usize

参数

self: *Prng
seed: usize

std.treap.Treap.remove

函数

第 240 行

fn remove(self: *Self, node: *Node) void

参数

self: *Self
node: *Node

std.treap.Treap.replace

函数

第 220 行

fn replace(self: *Self, old: *Node, new: *Node) void

参数

self: *Self
old: *Node
new: *Node

std.treap.Treap.rotate

函数

第 261 行

fn rotate(self: *Self, node: *Node, right: bool) void

参数

self: *Self
node: *Node
right: bool

std.treap.Treap.Self

别名

第 8 行

别名目标 std.treap.Treap

源码

std/treap.zig

const std = @import("std.zig");
const assert = std.debug.assert;
const testing = std.testing;
const Order = std.math.Order;

pub fn Treap(comptime Key: type, comptime compareFn: anytype) type {
    return struct {
        const Self = @This();

        // 允许 compareFn 为 fn (anytype, anytype) anytype,
        // 以便使用 std.math.order。
        fn compare(a: Key, b: Key) Order {
            return compareFn(a, b);
        }

        root: ?*Node = null,
        prng: Prng = .{},

        /// 为树堆定制的伪随机数生成器。
        /// 它仅用于减小树堆本身的内存大小,
        /// 因为 std.Random.DefaultPrng 需要更大的状态,当然也提供更好的随机熵。
        const Prng = struct {
            xorshift: usize = 0,

            fn random(self: *Prng, seed: usize) usize {
                // 延迟播种 PRNG 状态
                if (self.xorshift == 0) {
                    self.xorshift = seed;
                }

                // 由于使用 usize,根据该整数的位宽确定移位量。
                const shifts = switch (@bitSizeOf(usize)) {
                    64 => .{ 13, 7, 17 },
                    32 => .{ 13, 17, 5 },
                    16 => .{ 7, 9, 8 },
                    else => @compileError("platform not supported"),
                };

                self.xorshift ^= self.xorshift >> shifts[0];
                self.xorshift ^= self.xorshift << shifts[1];
                self.xorshift ^= self.xorshift >> shifts[2];

                assert(self.xorshift != 0);
                return self.xorshift;
            }
        };

        /// Node 表示树堆中的项目或节点,具有唯一关联键。
        pub const Node = struct {
            key: Key,
            priority: usize,
            parent: ?*Node,
            children: [2]?*Node,

            pub fn next(node: *Node) ?*Node {
                return nextOnDirection(node, 1);
            }
            pub fn prev(node: *Node) ?*Node {
                return nextOnDirection(node, 0);
            }
        };

        fn extremeInSubtreeOnDirection(node: *Node, direction: u1) *Node {
            var cur = node;
            while (cur.children[direction]) |next| cur = next;
            return cur;
        }

        fn nextOnDirection(node: *Node, direction: u1) ?*Node {
            if (node.children[direction]) |child| {
                return extremeInSubtreeOnDirection(child, direction ^ 1);
            }
            var cur = node;
            // 向上遍历,直到发现从 `parent` 到 `cur` 不位于
            // `direction`;等价地,从 `cur` 到 `parent` 位于
            // `direction`,因此 `parent` 就是下一个节点。
            while (true) {
                if (cur.parent) |parent| {
                    // 如果 `parent -> node` 不在 `direction` 方向上,
                    // 则 `node -> parent` 必在 `direction` 方向上。
                    if (parent.children[direction] != cur) return parent;
                    cur = parent;
                } else {
                    return null;
                }
            }
        }

        /// 返回树堆中按键最小的 Node(若存在)。
        /// 使用 `getEntryForExisting()` 替换或移除此 Node。
        pub fn getMin(self: Self) ?*Node {
            if (self.root) |root| return extremeInSubtreeOnDirection(root, 0);
            return null;
        }

        /// 返回树堆中按键最大的 Node(若存在)。
        /// 使用 `getEntryForExisting()` 替换或移除此 Node。
        pub fn getMax(self: Self) ?*Node {
            if (self.root) |root| return extremeInSubtreeOnDirection(root, 1);
            return null;
        }

        /// 在树堆中查找给定键的 Entry。
        /// Entry 充当树堆中的槽位,用于插入、替换或移除关联该键的节点。
        pub fn getEntryFor(self: *Self, key: Key) Entry {
            var parent: ?*Node = undefined;
            const node = self.find(key, &parent);

            return Entry{
                .key = key,
                .treap = self,
                .node = node,
                .context = .{ .inserted_under = parent },
            };
        }

        /// 获取当前存在于树堆中的 Node 的条目。
        /// 如果 Node 当前未插入树堆,则为未定义行为。
        /// Entry 充当树堆中的槽位,用于插入/替换/移除与该键关联的节点。
        pub fn getEntryForExisting(self: *Self, node: *Node) Entry {
            assert(node.priority != 0);

            return Entry{
                .key = node.key,
                .treap = self,
                .node = node,
                .context = .{ .inserted_under = node.parent },
            };
        }

        /// Entry 表示树堆中与给定键关联的槽位。
        pub const Entry = struct {
            /// 此条目关联的键。
            key: Key,
            /// 引用此条目所属的树堆。
            treap: *Self,
            /// 此条目处的当前节点。
            node: ?*Node,
            /// 条目的当前状态。
            context: union(enum) {
                /// 已对此条目调用 find(),其在树堆中的位置已知。
                inserted_under: ?*Node,
                /// 条目的节点已从树堆中移除,必须重新查找才能修改。
                removed,
            },

            /// 用新节点更新树堆中此 Entry 处的节点;null 表示删除。`new_node`
            /// 的内容可以为 `undefind`,因为会在内部初始化其值。
            pub fn set(self: *Entry, new_node: ?*Node) void {
                // 更新下方树堆后,更新条目的节点引用。
                defer self.node = new_node;

                if (self.node) |old| {
                    if (new_node) |new| {
                        self.treap.replace(old, new);
                        return;
                    }

                    self.treap.remove(old);
                    self.context = .removed;
                    return;
                }

                if (new_node) |new| {
                    // 先前的 treap.remove() 可能重新平衡了节点,
                    // 因此在删除后插入时,必须重新查找父节点。
                    // 这次查找不应找到节点,因为尚未执行插入。
                    var parent: ?*Node = undefined;
                    switch (self.context) {
                        .inserted_under => |p| parent = p,
                        .removed => assert(self.treap.find(self.key, &parent) == null),
                    }

                    self.treap.insert(self.key, parent, new);
                    self.context = .{ .inserted_under = parent };
                }
            }
        };

        fn find(self: Self, key: Key, parent_ref: *?*Node) ?*Node {
            var node = self.root;
            parent_ref.* = null;

            // 跟踪父节点的基本二分搜索。
            while (node) |current| {
                const order = compare(key, current.key);
                if (order == .eq) break;

                parent_ref.* = current;
                node = current.children[@intFromBool(order == .gt)];
            }

            return node;
        }

        fn insert(self: *Self, key: Key, parent: ?*Node, node: *Node) void {
            // 生成随机优先级,并准备将节点插入树中
            node.key = key;
            node.priority = self.prng.random(@intFromPtr(node));
            node.parent = parent;
            node.children = [_]?*Node{ null, null };

            // 使父节点指向新节点
            const link = if (parent) |p| &p.children[@intFromBool(compare(key, p.key) == .gt)] else &self.root;
            assert(link.* == null);
            link.* = node;

            // 按照节点优先级将其向上旋转,以平衡树
            while (node.parent) |p| {
                if (p.priority <= node.priority) break;

                const is_right = p.children[1] == node;
                assert(p.children[@intFromBool(is_right)] == node);

                const rotate_right = !is_right;
                self.rotate(p, rotate_right);
            }
        }

        fn replace(self: *Self, old: *Node, new: *Node) void {
            // 从旧节点复制值
            new.key = old.key;
            new.priority = old.priority;
            new.parent = old.parent;
            new.children = old.children;

            // 使父节点指向新节点
            const link = if (old.parent) |p| &p.children[@intFromBool(p.children[1] == old)] else &self.root;
            assert(link.* == old);
            link.* = new;

            // 将子节点的父指针指向新节点
            for (old.children) |child_node| {
                const child = child_node orelse continue;
                assert(child.parent == old);
                child.parent = new;
            }
        }

        fn remove(self: *Self, node: *Node) void {
            // 按照优先级将节点向下旋转,使其成为待移除的叶节点。
            while (node.children[0] orelse node.children[1]) |_| {
                self.rotate(node, rotate_right: {
                    const right = node.children[1] orelse break :rotate_right true;
                    const left = node.children[0] orelse break :rotate_right false;
                    break :rotate_right (left.priority < right.priority);
                });
            }

            // node 现在是叶节点;将父节点对它的引用置为 null 以移除。
            const link = if (node.parent) |p| &p.children[@intFromBool(p.children[1] == node)] else &self.root;
            assert(link.* == node);
            link.* = null;

            // 清理遗留资源
            node.priority = 0;
            node.parent = null;
            node.children = [_]?*Node{ null, null };
        }

        fn rotate(self: *Self, node: *Node, right: bool) void {
            // 若为右侧,将以下结构转换:
            //      parent -> (node (target YY adjacent) XX)
            //      parent -> (target YY (node adjacent XX))
            //
            // 若为左侧(!right),将以下结构转换:
            //      parent -> (node (target YY adjacent) XX)
            //      parent -> (target YY (node adjacent XX))
            const parent = node.parent;
            const target = node.children[@intFromBool(!right)] orelse unreachable;
            const adjacent = target.children[@intFromBool(right)];

            // 旋转子节点
            target.children[@intFromBool(right)] = node;
            node.children[@intFromBool(!right)] = adjacent;

            // 旋转父节点
            node.parent = target;
            target.parent = parent;
            if (adjacent) |adj| adj.parent = node;

            // 修复父节点链接
            const link = if (parent) |p| &p.children[@intFromBool(p.children[1] == node)] else &self.root;
            assert(link.* == node);
            link.* = target;
        }

        /// 用法示例:
        ///   var iter = treap.inorderIterator();
        ///   while (iter.next()) |node| {
        ///     ...
        ///   }
        pub const InorderIterator = struct {
            current: ?*Node,

            pub fn next(it: *InorderIterator) ?*Node {
                const current = it.current;
                it.current = if (current) |cur|
                    cur.next()
                else
                    null;
                return current;
            }
        };

        pub fn inorderIterator(self: *Self) InorderIterator {
            return .{ .current = self.getMin() };
        }
    };
}

// 用于以随机顺序遍历切片。
// https://lemire.me/blog/2017/09/18/visiting-all-values-in-an-array-exactly-once-in-random-order/
fn SliceIterRandomOrder(comptime T: type) type {
    return struct {
        rng: std.Random,
        slice: []T,
        index: usize = undefined,
        offset: usize = undefined,
        co_prime: usize,

        const Self = @This();

        pub fn init(slice: []T, rng: std.Random) Self {
            return Self{
                .rng = rng,
                .slice = slice,
                .co_prime = blk: {
                    if (slice.len == 0) break :blk 0;
                    var prime = slice.len / 2;
                    while (prime < slice.len) : (prime += 1) {
                        var gcd = [_]usize{ prime, slice.len };
                        while (gcd[1] != 0) {
                            const temp = gcd;
                            gcd = [_]usize{ temp[1], temp[0] % temp[1] };
                        }
                        if (gcd[0] == 1) break;
                    }
                    break :blk prime;
                },
            };
        }

        pub fn reset(self: *Self) void {
            self.index = 0;
            self.offset = self.rng.int(usize);
        }

        pub fn next(self: *Self) ?*T {
            if (self.index >= self.slice.len) return null;
            defer self.index += 1;
            return &self.slice[((self.index *% self.co_prime) +% self.offset) % self.slice.len];
        }
    };
}

const TestTreap = Treap(u64, std.math.order);
const TestNode = TestTreap.Node;

test "insert, find, replace, remove" {
    var treap = TestTreap{};
    var nodes: [10]TestNode = undefined;

    var prng = std.Random.DefaultPrng.init(0xdeadbeef);
    var iter = SliceIterRandomOrder(TestNode).init(&nodes, prng.random());

    // 插入检查
    iter.reset();
    while (iter.next()) |node| {
        const key = prng.random().int(u64);

        // 确保当前条目为空。
        var entry = treap.getEntryFor(key);
        try testing.expectEqual(entry.key, key);
        try testing.expectEqual(entry.node, null);

        // 插入条目,并确保各字段正确。
        entry.set(node);
        try testing.expectEqual(node.key, key);
        try testing.expectEqual(entry.key, key);
        try testing.expectEqual(entry.node, node);
    }

    // 查找检查
    iter.reset();
    while (iter.next()) |node| {
        const key = node.key;

        // 插入之后,分别按键和节点查找该条目。
        const entry = treap.getEntryFor(node.key);
        try testing.expectEqual(entry.key, key);
        try testing.expectEqual(entry.node, node);
        try testing.expectEqual(entry.node, treap.getEntryForExisting(node).node);
    }

    // 中序迭代器检查
    {
        var it = treap.inorderIterator();
        var last_key: u64 = 0;
        while (it.next()) |node| {
            try std.testing.expect(node.key >= last_key);
            last_key = node.key;
        }
    }

    // 替换检查
    iter.reset();
    while (iter.next()) |node| {
        const key = node.key;

        // 既然已知条目存在,则通过节点查找它。
        var entry = treap.getEntryForExisting(node);
        try testing.expectEqual(entry.key, key);
        try testing.expectEqual(entry.node, node);

        var stub_node: TestNode = undefined;

        // 将节点替换为 stub_node,并确保后续查找均指向该 stub_node。
        entry.set(&stub_node);
        try testing.expectEqual(entry.node, &stub_node);
        try testing.expectEqual(entry.node, treap.getEntryFor(key).node);
        try testing.expectEqual(entry.node, treap.getEntryForExisting(&stub_node).node);

        // 将 stub_node 恢复为 node,并确保后续查找仍指向旧节点。
        entry.set(node);
        try testing.expectEqual(entry.node, node);
        try testing.expectEqual(entry.node, treap.getEntryFor(key).node);
        try testing.expectEqual(entry.node, treap.getEntryForExisting(node).node);
    }

    // 移除检查
    iter.reset();
    while (iter.next()) |node| {
        const key = node.key;

        // 既然已知条目存在,则通过节点查找它。
        var entry = treap.getEntryForExisting(node);
        try testing.expectEqual(entry.key, key);
        try testing.expectEqual(entry.node, node);

        // 移除条目处的节点,并确保后续查找均反映其已被移除。
        entry.set(null);
        try testing.expectEqual(entry.node, null);
        try testing.expectEqual(entry.node, treap.getEntryFor(key).node);

        // 重新插入节点,并确保后续查找均指向已插入节点。
        entry.set(node);
        try testing.expectEqual(entry.node, node);
        try testing.expectEqual(entry.node, treap.getEntryFor(key).node);
        try testing.expectEqual(entry.node, treap.getEntryForExisting(node).node);

        // 再次移除节点,并确保插入后该节点已被清除。
        entry.set(null);
        try testing.expectEqual(entry.node, null);
        try testing.expectEqual(entry.node, treap.getEntryFor(key).node);
    }
}

test "inorderIterator" {
    var treap = TestTreap{};
    var nodes: [10]TestNode = undefined;

    // 构建树。
    var i: usize = 0;
    while (i < 10) : (i += 1) {
        const key = @as(u64, i);
        var entry = treap.getEntryFor(key);
        entry.set(&nodes[i]);
    }

    // 测试迭代器。
    var iter = treap.inorderIterator();
    i = 0;
    while (iter.next()) |node| {
        const key = @as(u64, i);
        try testing.expectEqual(key, node.key);
        i += 1;
    }
}

test "getMin, getMax, simple" {
    var treap = TestTreap{};
    var nodes: [3]TestNode = undefined;

    try testing.expectEqual(null, treap.getMin());
    try testing.expectEqual(null, treap.getMax());
    { // nodes[1]
        var entry = treap.getEntryFor(1);
        entry.set(&nodes[1]);
        try testing.expectEqual(&nodes[1], treap.getMin());
        try testing.expectEqual(&nodes[1], treap.getMax());
    }
    { // nodes[0]
        var entry = treap.getEntryFor(0);
        entry.set(&nodes[0]);
        try testing.expectEqual(&nodes[0], treap.getMin());
        try testing.expectEqual(&nodes[1], treap.getMax());
    }
    { // nodes[2]
        var entry = treap.getEntryFor(2);
        entry.set(&nodes[2]);
        try testing.expectEqual(&nodes[0], treap.getMin());
        try testing.expectEqual(&nodes[2], treap.getMax());
    }
}

test "getMin, getMax, random" {
    var nodes: [100]TestNode = undefined;
    var prng = std.Random.DefaultPrng.init(0xdeadbeef);
    var iter = SliceIterRandomOrder(TestNode).init(&nodes, prng.random());

    var treap = TestTreap{};
    var min: u64 = std.math.maxInt(u64);
    var max: u64 = 0;

    try testing.expectEqual(null, treap.getMin());
    try testing.expectEqual(null, treap.getMax());

    // 插入,并在每次插入后检查最小/最大值。
    iter.reset();
    while (iter.next()) |node| {
        const key = prng.random().int(u64);

        // 插入 `treap`。
        var entry = treap.getEntryFor(key);
        entry.set(node);

        if (key < min) min = key;
        if (key > max) max = key;

        const min_node = treap.getMin().?;
        try std.testing.expectEqual(null, min_node.prev());
        try std.testing.expectEqual(min, min_node.key);

        const max_node = treap.getMax().?;
        try std.testing.expectEqual(null, max_node.next());
        try std.testing.expectEqual(max, max_node.key);
    }
}

test "node.{prev(),next()} with sequential insertion and deletion" {
    // 插入顺序:50, 0, 1, 2, ..., 49, 51, 52, ..., 99。
    // 删除顺序:0, 1, 2, ..., 49, 51, 52, ..., 99。
    // 检查 50 的相邻节点。
    var treap = TestTreap{};
    var nodes: [100]TestNode = undefined;
    {
        var entry = treap.getEntryFor(50);
        entry.set(&nodes[50]);
        try testing.expectEqual(50, nodes[50].key);
        try testing.expectEqual(null, nodes[50].prev());
        try testing.expectEqual(null, nodes[50].next());
    }
    // 插入其他项。
    var i: usize = 0;
    while (i < 50) : (i += 1) {
        const key = @as(u64, i);
        const node = &nodes[i];
        var entry = treap.getEntryFor(key);
        entry.set(node);
        try testing.expectEqual(key, node.key);
        try testing.expectEqual(node, nodes[50].prev());
        try testing.expectEqual(null, nodes[50].next());
    }
    i = 51;
    while (i < 100) : (i += 1) {
        const key = @as(u64, i);
        const node = &nodes[i];
        var entry = treap.getEntryFor(key);
        entry.set(node);
        try testing.expectEqual(key, node.key);
        try testing.expectEqual(&nodes[49], nodes[50].prev());
        try testing.expectEqual(&nodes[51], nodes[50].next());
    }
    // 移除其他项。
    i = 0;
    while (i < 49) : (i += 1) {
        const key = @as(u64, i);
        var entry = treap.getEntryFor(key);
        entry.set(null);
        try testing.expectEqual(&nodes[49], nodes[50].prev());
        try testing.expectEqual(&nodes[51], nodes[50].next());
    }
    { // i = 49.
        const key = @as(u64, i);
        var entry = treap.getEntryFor(key);
        entry.set(null);
        try testing.expectEqual(null, nodes[50].prev());
        try testing.expectEqual(&nodes[51], nodes[50].next());
    }
    i = 51;
    while (i < 99) : (i += 1) {
        const key = @as(u64, i);
        var entry = treap.getEntryFor(key);
        entry.set(null);
        try testing.expectEqual(null, nodes[50].prev());
        try testing.expectEqual(&nodes[i + 1], nodes[50].next());
    }
    { // i = 99.
        const key = @as(u64, i);
        var entry = treap.getEntryFor(key);
        entry.set(null);
        try testing.expectEqual(null, nodes[50].prev());
        try testing.expectEqual(null, nodes[50].next());
    }
}

fn findFirstGreaterOrEqual(array: []u64, value: u64) usize {
    var i: usize = 0;
    while (i < array.len and array[i] < value) i += 1;
    return i;
}

fn testOrderedArrayAndTreapConsistency(array: []u64, treap: *TestTreap) !void {
    var i: usize = 0;
    while (i < array.len) : (i += 1) {
        const value = array[i];

        const entry = treap.getEntryFor(value);
        try testing.expect(entry.node != null);
        const node = entry.node.?;
        try testing.expectEqual(value, node.key);

        if (i == 0) {
            try testing.expectEqual(node.prev(), null);
        } else {
            try testing.expectEqual(node.prev(), treap.getEntryFor(array[i - 1]).node);
        }
        if (i + 1 == array.len) {
            try testing.expectEqual(node.next(), null);
        } else {
            try testing.expectEqual(node.next(), treap.getEntryFor(array[i + 1]).node);
        }
    }
}

test "node.{prev(),next()} with random data" {
    var nodes: [100]TestNode = undefined;
    var prng = std.Random.DefaultPrng.init(0xdeadbeef);
    var iter = SliceIterRandomOrder(TestNode).init(&nodes, prng.random());

    var treap = TestTreap{};
    // 速度较慢、实现简单但正确的参考实现。按序排列。
    var golden = std.array_list.Managed(u64).init(std.testing.allocator);
    defer golden.deinit();

    // 插入。
    iter.reset();
    while (iter.next()) |node| {
        const key = prng.random().int(u64);

        // 插入 `golden`。
        const i = findFirstGreaterOrEqual(golden.items, key);
        // 确保未找到。若找到,则是 `prng` 的问题。
        try testing.expect(i == golden.items.len or golden.items[i] > key);
        try golden.insert(i, key);

        // 插入 `treap`。
        var entry = treap.getEntryFor(key);
        entry.set(node);

        try testOrderedArrayAndTreapConsistency(golden.items, &treap);
    }

    // 删除。
    iter.reset();
    while (iter.next()) |node| {
        const key = node.key;

        // 从 `golden` 中删除。
        const i = findFirstGreaterOrEqual(golden.items, key);
        try testing.expect(i < golden.items.len);
        _ = golden.orderedRemove(i);

        // 从 `treap` 删除。
        var entry = treap.getEntryFor(key);
        try testing.expect(entry.node != null);
        entry.set(null);

        try testOrderedArrayAndTreapConsistency(golden.items, &treap);
    }
}