while
while 循环反复执行一个表达式,直到某个条件不再为真。
const expectEqual = @import("std").testing.expectEqual;
test "while basic" {
var i: usize = 0;
while (i < 10) {
i += 1;
}
try expectEqual(10, i);
}$ zig test test_while.zig
1/1 test_while.test.while basic...OK
All 1 tests passed.
使用 break 提前退出 while 循环。
const expectEqual = @import("std").testing.expectEqual;
test "while break" {
var i: usize = 0;
while (true) {
if (i == 10)
break;
i += 1;
}
try expectEqual(10, i);
}$ zig test test_while_break.zig
1/1 test_while_break.test.while break...OK
All 1 tests passed.
使用 continue 跳回循环开头。
const expectEqual = @import("std").testing.expectEqual;
test "while continue" {
var i: usize = 0;
while (true) {
i += 1;
if (i < 10)
continue;
break;
}
try expectEqual(10, i);
}$ zig test test_while_continue.zig
1/1 test_while_continue.test.while continue...OK
All 1 tests passed.
while 循环支持继续表达式,每次继续下一轮循环时执行。continue 关键字也会遵循此规则。
const expectEqual = @import("std").testing.expectEqual;
const expect = @import("std").testing.expect;
test "while loop continue expression" {
var i: usize = 0;
while (i < 10) : (i += 1) {}
try expectEqual(10, i);
}
test "while loop continue expression, more complicated" {
var i: usize = 1;
var j: usize = 1;
while (i * j < 2000) : ({
i *= 2;
j *= 3;
}) {
const my_ij = i * j;
try expect(my_ij < 2000);
}
}$ zig test test_while_continue_expression.zig
1/2 test_while_continue_expression.test.while loop continue expression...OK
2/2 test_while_continue_expression.test.while loop continue expression, more complicated...OK
All 2 tests passed.
while 循环是表达式。其结果是 while 循环的 else 子句的结果;当循环条件判断为假时执行该子句。
break 与 return 一样接受一个值参数,该值就是 while 表达式的结果。从 while 循环中执行 break 时,不会求值 else 分支。
const expect = @import("std").testing.expect;
test "while else" {
try expect(rangeHasNumber(0, 10, 5));
try expect(!rangeHasNumber(0, 10, 15));
}
fn rangeHasNumber(begin: usize, end: usize, number: usize) bool {
var i = begin;
return while (i < end) : (i += 1) {
if (i == number) {
break true;
}
} else false;
}$ zig test test_while_else.zig
1/1 test_while_else.test.while else...OK
All 1 tests passed.
带标签的 while
为 while 循环添加标签后,可以在嵌套循环中通过 break 或 continue 引用它:
test "nested break" {
outer: while (true) {
while (true) {
break :outer;
}
}
}
test "nested continue" {
var i: usize = 0;
outer: while (i < 10) : (i += 1) {
while (true) {
continue :outer;
}
}
}$ zig test test_while_nested_break.zig
1/2 test_while_nested_break.test.nested break...OK
2/2 test_while_nested_break.test.nested continue...OK
All 2 tests passed.
对可选值使用 while
与 if 表达式一样,while 循环可以将可选值作为条件并捕获载荷。遇到 null 时循环退出。
当 while 表达式使用 |x| 语法时,其循环条件必须具有可选类型。
遍历可选值时允许使用 else 分支;它会在首次遇到空值时执行。
const expectEqual = @import("std").testing.expectEqual;
test "while null capture" {
var sum1: u32 = 0;
numbers_left = 3;
while (eventuallyNullSequence()) |value| {
sum1 += value;
}
try expectEqual(3, sum1);
// 使用 else 块处理空值
var sum2: u32 = 0;
numbers_left = 3;
while (eventuallyNullSequence()) |value| {
sum2 += value;
} else {
try expectEqual(3, sum2);
}
// 带有继续表达式的可选值捕获
var i: u32 = 0;
var sum3: u32 = 0;
numbers_left = 3;
while (eventuallyNullSequence()) |value| : (i += 1) {
sum3 += value;
}
try expectEqual(3, i);
}
var numbers_left: u32 = undefined;
fn eventuallyNullSequence() ?u32 {
return if (numbers_left == 0) null else blk: {
numbers_left -= 1;
break :blk numbers_left;
};
}$ zig test test_while_null_capture.zig
1/1 test_while_null_capture.test.while null capture...OK
All 1 tests passed.
对错误联合使用 while
与 if 表达式一样,while 循环可以将错误联合作为条件,并捕获载荷或错误码。条件产生错误码时,会求值 else 分支并结束循环。
当 while 表达式使用 else |x| 语法时,其循环条件必须具有错误联合类型。
const expectEqual = @import("std").testing.expectEqual;
test "while error union capture" {
var sum1: u32 = 0;
numbers_left = 3;
while (eventuallyErrorSequence()) |value| {
sum1 += value;
} else |err| {
try expectEqual(error.ReachedZero, err);
}
}
var numbers_left: u32 = undefined;
fn eventuallyErrorSequence() anyerror!u32 {
return if (numbers_left == 0) error.ReachedZero else blk: {
numbers_left -= 1;
break :blk numbers_left;
};
}$ zig test test_while_error_capture.zig
1/1 test_while_error_capture.test.while error union capture...OK
All 1 tests passed.
inline while
while 循环可以内联。内联会展开循环,使代码能够执行仅在编译时可行的操作,例如将类型作为一等值使用。
const expectEqual = @import("std").testing.expectEqual;
test "inline while loop" {
comptime var i = 0;
var sum: usize = 0;
inline while (i < 3) : (i += 1) {
const T = switch (i) {
0 => f32,
1 => i8,
2 => bool,
else => unreachable,
};
sum += typeNameLength(T);
}
try expectEqual(9, sum);
}
fn typeNameLength(comptime T: type) usize {
return @typeName(T).len;
}$ zig test test_inline_while.zig
1/1 test_inline_while.test.inline while loop...OK
All 1 tests passed.
建议仅在以下情况之一成立时使用 inline 循环:
- 需要循环在编译时执行,才能实现所需语义。
- 已有基准测试证明,以这种方式强制展开循环会带来可测量的性能提升。
另见: