零位类型
某些类型的 @sizeOf 为 0:
这些类型仅有一个可能值,因此表示它们需要 0 位。使用这些类型的代码不会纳入最终生成的代码:
export fn entry() void {
var x: void = {};
var y: void = {};
x = y;
y = x;
}转化为机器码时,entry 的函数体中不生成任何代码,即使在 debug 模式下也是如此。例如在 x86_64 上:
0000000000000010 <entry>:
10: 55 push %rbp
11: 48 89 e5 mov %rsp,%rbp
14: 5d pop %rbp
15: c3 retq
这些汇编指令没有任何与 void 值相关的操作,只执行函数调用的序言与尾声。
void
void 可以用于实例化泛型类型。例如,对于 Map(Key, Value),可以向 Value 类型传入 void,使其成为 Set:
const std = @import("std");
const expect = std.testing.expect;
test "turn HashMap into a set with void" {
var map = std.AutoHashMap(i32, void).init(std.testing.allocator);
defer map.deinit();
try map.put(1, {});
try map.put(2, {});
try expect(map.contains(2));
try expect(!map.contains(3));
_ = map.remove(2);
try expect(!map.contains(2));
}$ zig test test_void_in_hashmap.zig
1/1 test_void_in_hashmap.test.turn HashMap into a set with void...OK
All 1 tests passed.
注意,这与为哈希映射的值使用占位值不同。使用 void 作为值类型后,哈希映射条目类型不包含值字段,因此映射占用的空间更小。此外,如上所示,所有存储和读取值的代码都会被删除。
void 与 anyopaque 不同。void 的大小已知为 0 字节,而 anyopaque 的大小未知但非零。
只有 void 类型表达式的值可以被忽略。例如,忽略非 void 表达式会产生编译错误:
test "ignoring expression value" {
foo();
}
fn foo() i32 {
return 1234;
}$ zig test test_expression_ignored.zig
/home/andy/src/zig/doc/langref/test_expression_ignored.zig:2:8: error: value of type 'i32' ignored
foo();
~~~^~
/home/andy/src/zig/doc/langref/test_expression_ignored.zig:2:8: note: all non-void values must be used
/home/andy/src/zig/doc/langref/test_expression_ignored.zig:2:8: note: to discard the value, assign it to '_'
但表达式类型为 void 时不会报错。可以通过赋值给 _ 显式忽略表达式结果。
test "void is ignored" {
returnsVoid();
}
test "explicitly ignoring expression value" {
_ = foo();
}
fn returnsVoid() void {}
fn foo() i32 {
return 1234;
}$ zig test test_void_ignored.zig
1/2 test_void_ignored.test.void is ignored...OK
2/2 test_void_ignored.test.explicitly ignoring expression value...OK
All 2 tests passed.